定义类映射文件

类映射文件是 HLA 集成的关键要素。HLA 接口节点模型中的 HLA-PM 使用该文件完成两项转换:

  • 将 Modeler 实体与 HLA 实体相互转换,如下表所示:

    表 3:Modeler–HLA 转换

    Modeler 实体 HLA 实体
    对象类型 对象类型
    属性 属性
    数据包 交互
    数据包字段 参数
  • 为 Modeler 实体指定数据类型。HLA 实体没有类型。

类映射文件的语法模仿 .fed 文件的语法,是用你选定的编辑器准备的文本文件。将其保存在与相关网络模型相同的目录中,文件扩展名为 .map。配置 HLA Class Mapping File 仿真属性,列出该文件的路径名。有关该属性的详细信息,见“HLA-PM Attributes”第 12 页。

定义类映射文件时应遵循的规则在本节中列出并讨论。有关规则的完整列表,见“Class Mapping File”第 41 页。

类映射文件

类映射文件的整体格式定义如下。该定义以及所有其它定义都使用 Backus-Naur Form(BNF)的一个子集来表示,其中粗体文本表示按原样键入的内容。有关所用约定的详细信息,见“BNF Notation”第 39 页。

<MapFile> ::= ( mapping version 2 [<Mapping>]+ )
<Mapping> ::= <TypeDefs> | <ObjectMaps> | <InterMaps>
  1. 为了反映 .fed 语法,映射被括在圆括号中,并以关键字 “mapping” 开头。目前的版本号为 2。如果映射语法将来出现新版本,将使用不同的编号。

  2. 映射可以包含类型定义(<TypeDefs>,见类型定义)、对象类映射(<ObjectMaps>,见对象与属性映射)和交互类映射(<InterMaps>,见交互/参数映射)。

类型定义

SOM/FOM 规范允许属性和参数使用枚举数据类型和复杂数据类型。枚举数据类型用于限定给定属性或参数的可能取值集合。

注: 虽然 Modeler 允许枚举数据类型,但它不检查枚举类型中的允许值。就映射而言,枚举的类型就是该枚举各取值的类型。

对于参数,HLA-PM 只处理基本类型的转换,更复杂的值以带有 structure 数据类型的字节块形式传递给目标进程模型。

HLA 属性和参数数据类型可分为三类,每类都有对应的 Modeler 表示形式。

  • 具有 SOM/FOM 基本数据类型(基数为 1 的整数、浮点和字符串数据类型)的 HLA 属性和参数可以直接映射到 Modeler 标量类型,如下表所示。

    表 4:SOM/FOM 到 Modeler 的数据类型映射

    SOM/FOM 基本类型 Modeler 类型
    string string
    short unsigned short
    long unsigned long
    long long unsigned long long¹
    char octet
    integer
    boolean boolean
    float double double

    注 1:long long 和 unsigned long long 类型的参数值不会被转换为整数。该值的字节表示被存储在 structure 字段中,由目标进程模型解析。

  • 具有 SOM/FOM 标量数组数据类型(基数大于 1 的整数、浮点和字符串数据类型)的 HLA 属性(但不包括参数)被映射到一个 Modeler 复合属性,该复合属性包含一个具有相应 Modeler 类型的标量子属性,如上表所示。

    具有标量数组数据类型的参数以带有 structure 数据类型的字节块形式交付给目标进程模型。

  • 复杂数据类型(等价于 C 结构体及结构体数组)的 HLA 属性被映射到一个 Modeler 复合属性,该复合属性包含 N 个子属性,每个子属性的 Modeler 类型与相应的 SOM/FOM 子数据类型相匹配。

    具有复杂数据类型的参数以带有 structure 数据类型的字节块形式交付给目标进程模型。

类型定义节的格式如下:

<TypeDefs> ::= ( types [<TypeDef>]+ )

<TypeDef> ::= ( <Name> [<FieldDefs>]+ )

<FieldDefs> ::= ( attribute <FOM_Name> <OPNET_Name> <Type> )

<Type> ::= <FOM_Type> | <Name>

<FOM_Type> ::= <IntegerType> | <FloatType> | boolean | string

<IntegerType> ::= short | unsigned_short | long | unsigned_long | long_long | unsigned_long_long	 | char | octet

<FloatType> ::= float | double

<OPNET_Name> 是复合结构的 Modeler 属性名。FOM 名称在映射期间并不使用,放在这里仅供参考。如果所表示的 FOM 类型是基数大于 1 的标量类型,FOM 名称输入 “none”。

下面的示例类型定义定义了类型 position2D 和 position3D,用于表示 2D 和 3D 空间中的位置。FOM 名称使用大写,Modeler 名称使用小写。

(types
   (position2D
      (attribute FOM_X opnet_x double)
      (attribute FOM_Y opnet_y double))
   (position3D
      (attribute FOM_2D opnet_2d position2D)
      (attribute FOM_Z opnet_z double)))

有关 HLA-PM 如何编码和解码各种数据类型值的说明,见表示属性与参数值。

对象与属性映射

对象与属性映射将 HLA 对象类与 Modeler 类型关联,将 HLA 属性与 Modeler 属性关联。HLA 对象类的每个属性不必都映射到相应 Modeler 类型的属性,反之亦然。未映射的 HLA 属性不会被 Riverbed 联邦成员看到;同样,未映射的 Modeler 属性也不会被其它联邦成员看到。

对象映射节的格式如下:

<ObjectMaps> ::= ( objects [<ObjMap>]+ )

<ObjMap> ::= ( class <ObjClass> [<ObjAttr>]+ [<ObjMap>]* )

<ObjClass> ::= <HLAClassName> <OpnetObject> <OpnetMobility> <ClassSet> <Create>

<OpnetObject> ::= node | subnet | all

<OpnetMobility> ::= fixed | mobile | satellite | any

<ClassSet> ::= ( class_set <OpnetObjectMatch> )

<OpnetObjectMatch> ::= ( <AttrName> <Oper> <Value> <OPNET_Type> ) |
	( not <OpnetObjectMatch> ) |
	( and <OpnetObjectMatch> <OpnetObjectMatch> ) |
	( or <OpnetObjectMatch> <OpnetObjectMatch> )

<Oper> ::= == | != | < | <= | > | >= | prefix | contains | suffix

<OPNET_Type> ::= integer | boolean | double | string

<Create> ::= ( creation_mode <CreateMode> )

<CreateMode> ::= create [ <AttrName> <Type> ] |
	discover <RTIMatch> |
	dynamic <RTIMatch>

<RTIMatch> ::= attr_match <AttrName> |
	name_match <AttrName> <Type>

<ObjAttr> ::= ( attribute <HLAName> <AttrName> <Type> <PS> )

<AttrName> ::= <Name> | <Name> [ <Number> ] . <AttrName>

<PS> ::= P | S
  • <ObjMap> 行——每个对象映射包含类级映射方法(<ObjClass> 行)和属性级映射列表(<ObjAttr> 行),其后是可选的 HLA 对象子类映射。

  • <ObjClass> 行——类级映射信息的解释如下:

    表 5:类级映射信息

    规则元素 解释
    <HLAClassName> HLA 类名
    <OpnetObject> Modeler 对象的种类(node、subnet 或 all),由 <OpnetObject> 规则指定
    <OpnetMobility> Modeler 移动性的种类(fixed、mobile、satellite 或 any),由 <OpnetMobility> 规则指定
    <ClassSet> 映射到该 HLA 类名的 Modeler 元素集合,由 <ClassSet> 规则指定
    <Create> 发现的 HLA 对象如何映射到 Modeler 对象,或如何从 Modeler 对象创建 HLA 对象,由 <Create> 规则指定
  • <ClassSet> 行——给定的 HLA 类可以映射到不同的 Modeler 对象集合。若某个对象满足 <OpnetObjectMatch> 行中指定的规则,则该对象属于这个集合。

  • <OpnetObjectMatch> 行——下面是 <OpnetObjectMatch> 规则的两个示例,其中 HLA 类与 Modeler 模型相匹配。第一种情况,一个 HLA 类 H1 映射到一个 Modeler 节点模型 NM,表示为:

    HLA 类 H1 映射到 Modeler 节点模型 NM

    在更复杂的情况下,HLA 类 H2 映射到名称中包含字符串 “Europe” 的固定子网:

    HLA 类 H2 映射到名称包含 Europe 的固定子网

    必须提供 Modeler 类型(string),以区分数值的字符串表示和真正的字符串。

    <AttrName> 部分应是 Modeler 元素的一个属性,不一定是要映射到 HLA 属性的那个属性。

  • <Oper> 行——关系运算符 <、<=、> 和 >= 只适用于数值属性。“prefix”、“contains” 和 “suffix” 只适用于字符串属性。

  • <Create> 行——指示仿真期间用于映射 Modeler 与 HLA 对象的创建模式。

  • <CreateMode> 行——指定用于创建 HLA 实例的创建模式(只能指定一种模式)。三种可能是:

    • create(为所有可能的 Modeler 对象创建 HLA 实例)——在仿真开始时,为所有匹配某条映射规则的 Modeler 对象创建 HLA 对象。仿真期间不会创建 HLA 对象,但可能会移除一些。不会发生 HLA 对象的发现。Modeler 对象集合是静态的,所有可能的匹配已经全部完成。对象名称使用指定属性生成。需要该属性类型,以便 HLA-PM 根据属性值生成字符串。只允许简单的属性类型(整数、浮点和字符串)。
    • discover(将发现的 HLA 实例映射到合适的 Modeler 对象,但不创建对象)。由其它联邦成员创建的 HLA 实例在仿真期间由 HLA 接口发现。仿真期间不会创建 HLA 对象,但可能会移除一些。
    • dynamic(映射发现的 HLA 实例,或允许创建 HLA 实例)。将由其它联邦成员创建的 HLA 实例映射到 Modeler 实例,或允许 Modeler 进程模型使用 op_hla_obj_create_notify() 按需创建 HLA 实例。
  • <RTMatch> 行——如果在 <Create> 规则中指定了 “discover” 或 “dynamic” 创建模式,使用此规则指定发现的 HLA 对象与 Modeler 对象的匹配方式。

    如果 HLA 对象有名称,使用 name_match。采用这种方法时,discoverObjectInstance() RTI 回调的 name 字段包含要与 Modeler 属性(通常是 name 属性)匹配的值。必须指明将与 HLA 名称值比较的 Modeler 属性及其类型。

    例如,假设你要将 HLA 类 Svr 中的对象映射到名称为 serverN(server1、server2 等)的 Modeler 对象。你可以编写如下规则:

    (class Svr node fixed
    	(class_set (name contains “server” string)
    	(creation_mode discover name_match name string)
    

    如果 HLA 对象没有名称,使用 attr_match。采用这种方法时,HLA-PM 将 HLA 属性与 Modeler 属性相匹配。参与比较的 Modeler 属性应出现在属性映射列表中,将其与已映射的 HLA 属性的值进行比较。属性匹配不需要类型信息,因为它已在属性映射信息中给出。

    例如,假设你要将具有属性 serial_number 的 HLA 类 Soldier 中的对象映射到具有属性 user id 的模型 soldat 的 Modeler 对象。你可以编写如下规则:

    (class Soldier node fixed
    	(class_set (model == soldat string))
    	(creation_mode discover attr_match “user id” )
    	(attribute serial_number “user id” short S)
    

    使用引号是为了让 Modeler 将字符串 “user id” 解释为单个实体,即使其中包含空格。

  • <ObjAttr> 行——属性级映射括在圆括号中,以关键字 “attribute” 开头,其后是 HLA 属性名(<HLAName>)、Modeler 属性名(<AttrName>)、属性类型(<Type>)以及发布/订阅信息(<PS>)。

    类型名(<Type>)必须先定义才能使用(见类型定义)。

  • <AttrName> 行——在大多数情况下,Modeler 属性名就是该属性本身(例如 x position)。对于复合属性,属性名可以是复合体某个子对象的属性,如 “subqueue[3].bit capacity”。如果名称中包含空格,必须使用引号。

  • <PS> 行——发布(P)一个属性表示该属性可以由本联邦成员修改(前提是本联邦成员拥有该属性的所有权)。订阅(S)一个属性表示当该属性的值被其它联邦成员修改时,本联邦成员希望得到通知。

下面的示例展示了如何应用 <ObjMap>、<ClassSet>、<RTMatch> 和 <PS> 行中所示的规则,将以 .fed 表示的 HLA 类 Tank 映射到所有名称中包含字符串 “Europe” 的 Modeler 移动子网。匹配使用 Modeler 属性 node_id。

HLA 类 Tank 到名称包含 Europe 的 Modeler 移动子网的映射

交互/参数映射

与 HLA 交互对应的 Modeler 结构是数据包,它有名称(具有特定的大小和数据类型)和字段(每个字段具有特定的大小和数据)。字段对应交互参数。在本 HLA 集成中使用的数据包并不代表实际的通信数据包,它们只是表示 HLA 交互的、正在交付的字节块。HLA 交互的接收由 HLA-PM 映射到相应模块上的 Modeler 流中断(见处理传入数据)。

HLA 交互与 Modeler 数据包之间的映射遵循你在类映射文件的交互映射节中包含的规则。使用以下格式。

<InterMaps> ::= ( interactions [<InterMap>]+ )

<InterMap> ::= ( class <InterClass> [<InterParam>]+ [<InterMap>]* )

<InterClass> ::= <HLAInteractionName> <OPNETPacketName>

<InterParam> ::= ( parameter <HLAParamName> <OPNETFieldName> <HLAParamType> )

<HLAParamName> ::= <Name> | <tag>

<HLAParamType> ::= <IntegerType> | <FloatType> | boolean | structure
  • <InterMaps> 行——一组交互映射括在圆括号中。该组以关键字 “interactions” 开头,其后是一个或多个交互映射。

  • <InterMap> 行——每个交互映射括在圆括号中。它以关键字 “class” 开头,其后是类级映射(<InterClass>)和参数级映射列表(<InterParam>)。HLA 交互子类的映射放在父类映射中参数级映射之后。

  • <InterClass> 行——类级映射是 HLA 交互的名称和 Modeler 数据包结构的名称。

  • <InterParam> 行——每个参数级映射括在圆括号中。它以关键字 “parameter” 开头,其后是 HLA 参数名(<HLAParamName>)、Modeler 字段名(<OPNETFieldName>)和 HLA 参数的类型(<HLAParamType>)。

  • <HLAParamName> 行——特殊名称 <tag> 表示随交互接收的任何 tag 值都应放入所创建数据包的相应字段。如果映射中没有 <tag>,则不会将任何 tag 值传递给接收该交互的进程模型。<tag> 记号的使用是可选的。

  • <HLAParamType> 行——基数为 1 的整数、浮点和布尔数据类型会被转换。布尔 FOM 值应存储在整数数据包字段中。其它数据类型被转换为字节块(structure)。见交付交互和生成交互。

    long long 和 unsigned long long 类型的值不会被转换为 Modeler 整数字段类型。在这些情况下,应将数据包字段类型指定为 structure,以便目标进程模型提取相应的值。

SOM 还规定联邦成员发起、感知或处理哪些交互。该信息不属于映射文件的一部分。见交付交互和生成交互。

下面的示例展示了如何应用 <InterMap> 和 <InterParam> 行中定义的规则,将以 .fed 表示的 HLA 交互 MoveTank 映射到 Modeler 数据包 move_tank,其字段为 “id”、“latitude move” 和 “longitude move”。

HLA 交互 MoveTank 到 Modeler 数据包 move_tank 的映射

规则约束

映射文件中可能出现多条映射规则适用于同一对象类的情况。HLA-PM 强制以下约束。

  • 一个 HLA 对象类只能映射一次。如果文件中包含适用于同一 HLA 对象类的多条规则,将产生解析错误。

  • 给定类的每个 HLA 属性只能映射一次。多条规则会产生解析错误。

  • 一个 HLA 交互类只能映射一次。多条规则会产生解析错误。

  • 给定交互的每个 HLA 参数只能映射一次。多条规则会产生解析错误。

  • 如果多条规则适用于同一个 Modeler 对象类,则使用解析映射文件时遇到的第一条适用规则。例如,假设你编写了如下两条映射规则:

    适用于同一 Modeler 对象类的两条映射规则

    任何名称中包含字符串 A 的 Modeler 对象(包括名为 AB 或 BA 的对象)都会被映射到 Class_A。Class_B 的规则永远不会应用于这些情况。

本站文档由 北京智网畅联科技有限公司 整理、翻译并提供 · Documentation compiled and provided by Beijing ZNetLink Technology Co., Ltd.

交流群 · QQ Group:OPNET/智网妙算网络仿真交流群(群号 486383494)

原文档 © 2017 Riverbed Technology · 本站为公益翻译,由 AI 辅助完成,请仔细甄别

Original documentation © 2017 Riverbed Technology. Community translation, AI-assisted. Contact: jiazequn@znetlink.com